### Conversions and similar elementary functions or commands

#### Col(x, {n})

Transforms the object x into a column vector. The dimension of the resulting vector can be optionally specified via the extra parameter n.

If n is omitted or 0, the dimension depends on the type of x; the vector has a single component, except when x is

* a vector or a quadratic form (in which case the resulting vector is simply the initial object considered as a row vector),

* a polynomial or a power series. In the case of a polynomial, the coefficients of the vector start with the leading coefficient of the polynomial, while for power series only the significant coefficients are taken into account, but this time by increasing order of degree. In this last case, `Vec` is the reciprocal function of `Pol` and `Ser` respectively,

* a matrix (the column of row vector comprising the matrix is returned),

* a character string (a vector of individual characters is returned).

In the last two cases (matrix and character string), n is meaningless and must be omitted or an error is raised. Otherwise, if n is given, 0 entries are appended at the end of the vector if n > 0, and prepended at the beginning if n < 0. The dimension of the resulting vector is |n|.

Note that the function `Colrev` does not exist, use `Vecrev`.

The library syntax is `GEN gtocol0(GEN x, long n)`. `GEN gtocol(GEN x)` is also available.

#### Colrev(x, {n})

As `Col`(x, n), then reverse the result. In particular

The library syntax is `GEN gtocolrev0(GEN x, long n)`. `GEN gtocolrev(GEN x)` is also available.

#### List({x = []})

Transforms a (row or column) vector x into a list, whose components are the entries of x. Similarly for a list, but rather useless in this case. For other types, creates a list with the single element x. Note that, except when x is omitted, this function creates a small memory leak; so, either initialize all lists to the empty list, or use them sparingly.

The library syntax is `GEN gtolist(GEN x = NULL)`. The variant `GEN listcreate(void)` creates an empty list.

#### Mat({x = []})

Transforms the object x into a matrix. If x is already a matrix, a copy of x is created. If x is a row (resp. column) vector, this creates a 1-row (resp. 1-column) matrix, unless all elements are column (resp. row) vectors of the same length, in which case the vectors are concatenated sideways and the associated big matrix is returned. If x is a binary quadratic form, creates the associated 2 x 2 matrix. Otherwise, this creates a 1 x 1 matrix containing x.

      ? Mat(x + 1)
      %1 =
      [x + 1]
      ? Vec( matid(3) )
      %2 = [[1, 0, 0]~, [0, 1, 0]~, [0, 0, 1]~]
      ? Mat(%)
      %3 =
      [1 0 0]

      [0 1 0]

      [0 0 1]
      ? Col( [1,2; 3,4] )
      %4 = [[1, 2], [3, 4]]~
      ? Mat(%)
      %5 =
      [1 2]

      [3 4]
      ? Mat(Qfb(1,2,3))
      %6 =
      [1 1]

      [1 3]

The library syntax is `GEN gtomat(GEN x = NULL)`.

#### Mod(a,b)

In its basic form, creates an intmod or a polmod (a mod b); b must be an integer or a polynomial. We then obtain a `t_INTMOD` and a `t_POLMOD` respectively:

      ? t = Mod(2,17); t^8
      %1 = Mod(1, 17)
      ? t = Mod(x,x^2+1); t^2
      %2 = Mod(-1, x^2+1)

If a % b makes sense and yields a result of the appropriate type (`t_INT` or scalar/`t_POL`), the operation succeeds as well:

      ? Mod(1/2, 5)
      %3 = Mod(3, 5)
      ? Mod(7 + O(3^6), 3)
      %4 = Mod(1, 3)
      ? Mod(Mod(1,12), 9)
      %5 = Mod(1, 3)
      ? Mod(1/x, x^2+1)
      %6 = Mod(-1, x^2+1)
      ? Mod(exp(x), x^4)
      %7 = Mod(1/6*x^3 + 1/2*x^2 + x + 1, x^4)

If a is a complex object, "base change" it to Z/bZ or K[x]/(b), which is equivalent to, but faster than, multiplying it by `Mod(1,b)`:

      ? Mod([1,2;3,4], 2)
      %8 =
      [Mod(1, 2) Mod(0, 2)]

      [Mod(1, 2) Mod(0, 2)]
      ? Mod(3*x+5, 2)
      %9 = Mod(1, 2)*x + Mod(1, 2)
      ? Mod(x^2 + y*x + y^3, y^2+1)
      %10 = Mod(1, y^2 + 1)*x^2 + Mod(y, y^2 + 1)*x + Mod(-y, y^2 + 1)

This function is not the same as x `%` y, the result of which has no knowledge of the indended modulus y. Compare

      ? x = 4 % 5; x + 1
      %1 = 5
      ? x = Mod(4,5); x + 1
      %2 = Mod(0,5)

The library syntax is `GEN gmodulo(GEN a, GEN b)`.

#### Pol(t,{v = 'x})

Transforms the object t into a polynomial with main variable v. If t is a scalar, this gives a constant polynomial. If t is a power series with non-negative valuation or a rational function, the effect is similar to `truncate`, i.e. we chop off the O(X^k) or compute the Euclidean quotient of the numerator by the denominator, then change the main variable of the result to v.

The main use of this function is when t is a vector: it creates the polynomial whose coefficients are given by t, with t[1] being the leading coefficient (which can be zero). It is much faster to evaluate `Pol` on a vector of coefficients in this way, than the corresponding formal expression a_n X^n +...+ a_0, which is evaluated naively exactly as written (linear versus quadratic time in n). `Polrev` can be used if one wants x[1] to be the constant coefficient:

      ? Pol([1,2,3])
      %1 = x^2 + 2*x + 3
      ? Polrev([1,2,3])
      %2 = 3*x^2 + 2*x + 1

The reciprocal function of `Pol` (resp. `Polrev`) is `Vec` (resp. `Vecrev`).

      ? Vec(Pol([1,2,3]))
      %1 = [1, 2, 3]
      ? Vecrev( Polrev([1,2,3]) )
      %2 = [1, 2, 3]

Warning. This is not a substitution function. It will not transform an object containing variables of higher priority than v.

      ? Pol(x + y, y)
        ***   at top-level: Pol(x+y,y)
        ***                 ^----------
        *** Pol: variable must have higher priority in gtopoly.

The library syntax is `GEN gtopoly(GEN t, long v = -1)`, where `v` is a variable number.

#### Polrev(t,{v = 'x})

Transform the object t into a polynomial with main variable v. If t is a scalar, this gives a constant polynomial. If t is a power series, the effect is identical to `truncate`, i.e. it chops off the O(X^k).

The main use of this function is when t is a vector: it creates the polynomial whose coefficients are given by t, with t[1] being the constant term. `Pol` can be used if one wants t[1] to be the leading coefficient:

      ? Polrev([1,2,3])
      %1 = 3*x^2 + 2*x + 1
      ? Pol([1,2,3])
      %2 = x^2 + 2*x + 3

The reciprocal function of `Pol` (resp. `Polrev`) is `Vec` (resp. `Vecrev`).

The library syntax is `GEN gtopolyrev(GEN t, long v = -1)`, where `v` is a variable number.

#### Qfb(a,b,c,{D = 0.})

Creates the binary quadratic form ax^2+bxy+cy^2. If b^2-4ac > 0, initialize Shanks' distance function to D. Negative definite forms are not implemented, use their positive definite counterpart instead.

The library syntax is `GEN Qfb0(GEN a, GEN b, GEN c, GEN D = NULL, long prec)`. Also available are `GEN qfi(GEN a, GEN b, GEN c)` (assumes b^2-4ac < 0) and `GEN qfr(GEN a, GEN b, GEN c, GEN D)` (assumes b^2-4ac > 0).

#### Ser(s,{v = 'x},{d = seriesprecision})

Transforms the object s into a power series with main variable v (x by default) and precision (number of significant terms) equal to d ( = the default `seriesprecision` by default). If s is a scalar, this gives a constant power series in v with precision `d`. If s is a polynomial, the polynomial is truncated to d terms if needed

      ? Ser(1, 'y, 5)
      %1 = 1 + O(y^5)
      ? Ser(x^2,, 5)
      %2 = x^2 + O(x^7)
      ? T = polcyclo(100)
      %3 = x^40 - x^30 + x^20 - x^10 + 1
      ? Ser(T, 'x, 11)
      %4 = 1 - x^10 + O(x^11)

The function is more or less equivalent with multiplication by 1 + O(v^d) in theses cases, only faster.

If s is a vector, on the other hand, the coefficients of the vector are understood to be the coefficients of the power series starting from the constant term (as in `Polrev`(x)), and the precision d is ignored: in other words, in this case, we convert `t_VEC` / `t_COL` to the power series whose significant terms are exactly given by the vector entries. Finally, if s is already a power series in v, we return it verbatim, ignoring d again. If d significant terms are desired in the last two cases, convert/truncate to `t_POL` first.

      ? v = [1,2,3]; Ser(v, t, 7)
      %5 = 1 + 2*t + 3*t^2 + O(t^3)  \\ 3 terms: 7 is ignored!
      ? Ser(Polrev(v,t), t, 7)
      %6 = 1 + 2*t + 3*t^2 + O(t^7)
      ? s = 1+x+O(x^2); Ser(s, x, 7)
      %7 = 1 + x + O(x^2)  \\ 2 terms: 7 ignored
      ? Ser(truncate(s), x, 7)
      %8 = 1 + x + O(x^7)

The warning given for `Pol` also applies here: this is not a substitution function.

The library syntax is `GEN gtoser(GEN s, long v = -1, long precdl)`, where `v` is a variable number.

#### Set({x = []})

Converts x into a set, i.e. into a row vector, with strictly increasing entries with respect to the (somewhat arbitrary) universal comparison function `cmp`. Standard container types `t_VEC`, `t_COL`, `t_LIST` and `t_VECSMALL` are converted to the set with corresponding elements. All others are converted to a set with one element.

      ? Set([1,2,4,2,1,3])
      %1 = [1, 2, 3, 4]
      ? Set(x)
      %2 = [x]
      ? Set(Vecsmall([1,3,2,1,3]))
      %3 = [1, 2, 3]

The library syntax is `GEN gtoset(GEN x = NULL)`.

#### Str({x}*)

Converts its argument list into a single character string (type `t_STR`, the empty string if x is omitted). To recover an ordinary `GEN` from a string, apply `eval` to it. The arguments of `Str` are evaluated in string context, see Section [Label: se:strings].

      ? x2 = 0; i = 2; Str(x, i)
      %1 = "x2"
      ? eval(%)
      %2 = 0

This function is mostly useless in library mode. Use the pair `strtoGEN`/`GENtostr` to convert between `GEN` and `char*`. The latter returns a malloced string, which should be freed after usage.

#### Strchr(x)

Converts x to a string, translating each integer into a character.

      ? Strchr(97)
      %1 = "a"
      ? Vecsmall("hello world")
      %2 = Vecsmall([104, 101, 108, 108, 111, 32, 119, 111, 114, 108, 100])
      ? Strchr(%)
      %3 = "hello world"

The library syntax is `GEN Strchr(GEN x)`.

#### Strexpand({x}*)

Converts its argument list into a single character string (type `t_STR`, the empty string if x is omitted). Then perform environment expansion, see Section [Label: se:envir]. This feature can be used to read environment variable values.

      ? Strexpand("$HOME/doc")
      %1 = "/home/pari/doc"

The individual arguments are read in string context, see Section [Label: se:strings].

#### Strtex({x}*)

Translates its arguments to TeX format, and concatenates the results into a single character string (type `t_STR`, the empty string if x is omitted).

The individual arguments are read in string context, see Section [Label: se:strings].

#### Vec(x, {n})

Transforms the object x into a row vector. The dimension of the resulting vector can be optionally specified via the extra parameter n.

If n is omitted or 0, the dimension depends on the type of x; the vector has a single component, except when x is

* a vector or a quadratic form (in which case the resulting vector is simply the initial object considered as a row vector),

* a polynomial or a power series. In the case of a polynomial, the coefficients of the vector start with the leading coefficient of the polynomial, while for power series only the significant coefficients are taken into account, but this time by increasing order of degree. In this last case, `Vec` is the reciprocal function of `Pol` and `Ser` respectively,

* a matrix: return the vector of columns comprising the matrix.

* a character string: return the vector of individual characters.

* an error context (`t_ERROR`): return the error components, see `iferr`.

In the last three cases (matrix, character string, error), n is meaningless and must be omitted or an error is raised. Otherwise, if n is given, 0 entries are appended at the end of the vector if n > 0, and prepended at the beginning if n < 0. The dimension of the resulting vector is |n|. Variant: `GEN gtovec(GEN x)` is also available.

The library syntax is `GEN gtovec0(GEN x, long n)`.

#### Vecrev(x, {n})

As `Vec`(x, n), then reverse the result. In particular In this case, `Vecrev` is the reciprocal function of `Polrev`: the coefficients of the vector start with the constant coefficient of the polynomial and the others follow by increasing degree.

The library syntax is `GEN gtovecrev0(GEN x, long n)`. `GEN gtovecrev(GEN x)` is also available.

#### Vecsmall(x, {n})

Transforms the object x into a row vector of type `t_VECSMALL`. The dimension of the resulting vector can be optionally specified via the extra parameter n.

This acts as `Vec`(x,n), but only on a limited set of objects: the result must be representable as a vector of small integers. If x is a character string, a vector of individual characters in ASCII encoding is returned (`Strchr` yields back the character string).

The library syntax is `GEN gtovecsmall0(GEN x, long n)`. `GEN gtovecsmall(GEN x)` is also available.

#### binary(x)

Outputs the vector of the binary digits of |x|. Here x can be an integer, a real number (in which case the result has two components, one for the integer part, one for the fractional part) or a vector/matrix.

The library syntax is `GEN binaire(GEN x)`.

#### bitand(x,y)

Bitwise `and` of two integers x and y, that is the integer sum_i (x_i `and` y_i) 2^i

Negative numbers behave 2-adically, i.e. the result is the 2-adic limit of `bitand`(x_n,y_n), where x_n and y_n are non-negative integers tending to x and y respectively. (The result is an ordinary integer, possibly negative.)

      ? bitand(5, 3)
      %1 = 1
      ? bitand(-5, 3)
      %2 = 3
      ? bitand(-5, -3)
      %3 = -7

The library syntax is `GEN gbitand(GEN x, GEN y)`. Also available is `GEN ibitand(GEN x, GEN y)`, which returns the bitwise and of |x| and |y|, two integers.

#### bitneg(x,{n = -1})

bitwise negation of an integer x, truncated to n bits, n `>=` 0, that is the integer sum_{i = 0}^{n-1} `not`(x_i) 2^i. The special case n = -1 means no truncation: an infinite sequence of leading 1 is then represented as a negative number.

See Section [Label: se:bitand] for the behavior for negative arguments.

The library syntax is `GEN gbitneg(GEN x, long n)`.

#### bitnegimply(x,y)

Bitwise negated imply of two integers x and y (or `not` (x ==> y)), that is the integer sum (x_i `and not`(y_i)) 2^i

See Section [Label: se:bitand] for the behavior for negative arguments.

The library syntax is `GEN gbitnegimply(GEN x, GEN y)`. Also available is `GEN ibitnegimply(GEN x, GEN y)`, which returns the bitwise negated imply of |x| and |y|, two integers.

#### bitor(x,y)

bitwise (inclusive) `or` of two integers x and y, that is the integer sum (x_i `or` y_i) 2^i

See Section [Label: se:bitand] for the behavior for negative arguments.

The library syntax is `GEN gbitor(GEN x, GEN y)`. Also available is `GEN ibitor(GEN x, GEN y)`, which returns the bitwise ir of |x| and |y|, two integers.

#### bittest(x,n)

Outputs the n-th bit of x starting from the right (i.e. the coefficient of 2^n in the binary expansion of x). The result is 0 or 1.

      ? bittest(7, 3)
      %1 = 1 \\ the 3rd bit is 1
      ? bittest(7, 4)
      %2 = 0 \\ the 4th bit is 0

See Section [Label: se:bitand] for the behavior at negative arguments.

The library syntax is `GEN gbittest(GEN x, long n)`. For a `t_INT` x, the variant `long bittest(GEN x, long n)` is generally easier to use, and if furthermore n `>=` 0 the low-level function `ulong int_bit(GEN x, long n)` returns `bittest(abs(x),n)`.

#### bitxor(x,y)

Bitwise (exclusive) `or` of two integers x and y, that is the integer sum (x_i `xor` y_i) 2^i

See Section [Label: se:bitand] for the behavior for negative arguments.

The library syntax is `GEN gbitxor(GEN x, GEN y)`. Also available is `GEN ibitxor(GEN x, GEN y)`, which returns the bitwise xor of |x| and |y|, two integers.

#### ceil(x)

Ceiling of x. When x is in R, the result is the smallest integer greater than or equal to x. Applied to a rational function, `ceil`(x) returns the Euclidean quotient of the numerator by the denominator.

The library syntax is `GEN gceil(GEN x)`.

#### centerlift(x,{v})

Same as `lift`, except that `t_INTMOD` and `t_PADIC` components are lifted using centered residues:

* for a `t_INTMOD` x belongs to Z/nZ, the lift y is such that -n/2 < y `<=` n/2.

* a `t_PADIC` x is lifted in the same way as above (modulo p^`padicprec(x)`) if its valuation v is non-negative; if not, returns the fraction p^v `centerlift`(x p^{-v}); in particular, rational reconstruction is not attempted. Use `bestappr` for this.

For backward compatibility, `centerlift(x,'v)` is allowed as an alias for `lift(x,'v)`.

The library syntax is `centerlift(GEN x)`.

#### characteristic(x)

Returns the characteristic of the base ring over which x is defined (as defined by `t_INTMOD` and `t_FFELT` components). The function raises an exception if incompatible primes arise from `t_FFELT` and `t_PADIC` components.

      ? characteristic(Mod(1,24)*x + Mod(1,18)*y)
      %1 = 6

The library syntax is `GEN characteristic(GEN x)`.

#### component(x,n)

Extracts the n-th-component of x. This is to be understood as follows: every PARI type has one or two initial code words. The components are counted, starting at 1, after these code words. In particular if x is a vector, this is indeed the n-th-component of x, if x is a matrix, the n-th column, if x is a polynomial, the n-th coefficient (i.e. of degree n-1), and for power series, the n-th significant coefficient.

For polynomials and power series, one should rather use `polcoeff`, and for vectors and matrices, the `[]` operator. Namely, if x is a vector, then `x[n]` represents the n-th component of x. If x is a matrix, `x[m,n]` represents the coefficient of row `m` and column `n` of the matrix, `x[m,]` represents the m-th row of x, and `x[,n]` represents the n-th column of x.

Using of this function requires detailed knowledge of the structure of the different PARI types, and thus it should almost never be used directly. Some useful exceptions:

          ? x = 3 + O(3^5);
          ? component(x, 2)
          %2 = 81   \\ p^(p-adic accuracy)
          ? component(x, 1)
          %3 = 3    \\ p
          ? q = Qfb(1,2,3);
          ? component(q, 1)
          %5 = 1

The library syntax is `GEN compo(GEN x, long n)`.

#### conj(x)

Conjugate of x. The meaning of this is clear, except that for real quadratic numbers, it means conjugation in the real quadratic field. This function has no effect on integers, reals, intmods, fractions or p-adics. The only forbidden type is polmod (see `conjvec` for this).

The library syntax is `GEN gconj(GEN x)`.

#### conjvec(z)

Conjugate vector representation of z. If z is a polmod, equal to `Mod`(a,T), this gives a vector of length {degree}(T) containing:

* the complex embeddings of z if T has rational coefficients, i.e. the a(r[i]) where r = `polroots`(T);

* the conjugates of z if T has some intmod coefficients;

if z is a finite field element, the result is the vector of conjugates [z,z^p,z^{p^2},...,z^{p^{n-1}}] where n = {degree}(T).

If z is an integer or a rational number, the result is z. If z is a (row or column) vector, the result is a matrix whose columns are the conjugate vectors of the individual elements of z.

The library syntax is `GEN conjvec(GEN z, long prec)`.

#### denominator(x)

Denominator of x. The meaning of this is clear when x is a rational number or function. If x is an integer or a polynomial, it is treated as a rational number or function, respectively, and the result is equal to 1. For polynomials, you probably want to use

      denominator( content(x) )

instead. As for modular objects, `t_INTMOD` and `t_PADIC` have denominator 1, and the denominator of a `t_POLMOD` is the denominator of its (minimal degree) polynomial representative.

If x is a recursive structure, for instance a vector or matrix, the lcm of the denominators of its components (a common denominator) is computed. This also applies for `t_COMPLEX`s and `t_QUAD`s.

Warning. Multivariate objects are created according to variable priorities, with possibly surprising side effects (x/y is a polynomial, but y/x is a rational function). See Section [Label: se:priority].

The library syntax is `GEN denom(GEN x)`.

#### digits(x,{b = 10})

Outputs the vector of the digits of |x| in base b, where x and b are integers.

The library syntax is `GEN digits(GEN x, GEN b = NULL)`.

#### floor(x)

Floor of x. When x is in R, the result is the largest integer smaller than or equal to x. Applied to a rational function, `floor`(x) returns the Euclidean quotient of the numerator by the denominator.

The library syntax is `GEN gfloor(GEN x)`.

#### frac(x)

Fractional part of x. Identical to x-{floor}(x). If x is real, the result is in [0,1[.

The library syntax is `GEN gfrac(GEN x)`.

#### hammingweight(x)

If x is a `t_INT`, return the binary Hamming weight of |x|. Otherwise x must be of type `t_POL`, `t_VEC`, `t_COL`, `t_VECSMALL`, or `t_MAT` and the function returns the number of non-zero coefficients of x.

      ? hammingweight(15)
      %1 = 4
      ? hammingweight(x^100 + 2*x + 1)
      %2 = 3
      ? hammingweight([Mod(1,2), 2, Mod(0,3)])
      %3 = 2
      ? hammingweight(matid(100))
      %4 = 100

The library syntax is `long hammingweight(GEN x)`.

#### imag(x)

Imaginary part of x. When x is a quadratic number, this is the coefficient of omega in the "canonical" integral basis (1,omega).

The library syntax is `GEN gimag(GEN x)`.

#### length(x)

Length of x; `#`x is a shortcut for `length`(x). This is mostly useful for

* vectors: dimension (0 for empty vectors),

* lists: number of entries (0 for empty lists),

* matrices: number of columns,

* character strings: number of actual characters (without trailing `\0`, should you expect it from C `char*`).

       ? #"a string"
       %1 = 8
       ? #[3,2,1]
       %2 = 3
       ? #[]
       %3 = 0
       ? #matrix(2,5)
       %4 = 5
       ? L = List([1,2,3,4]); #L
       %5 = 4

The routine is in fact defined for arbitrary GP types, but is awkward and useless in other cases: it returns the number of non-code words in x, e.g. the effective length minus 2 for integers since the `t_INT` type has two code words.

The library syntax is `long glength(GEN x)`.

#### lift(x,{v})

If v is omitted, lifts intmods from Z/nZ in Z, p-adics from Q_p to Q (as `truncate`), and polmods to polynomials. Otherwise, lifts only polmods whose modulus has main variable v. `t_FFELT` are not lifted, nor are List elements: you may convert the latter to vectors first, or use `apply(lift,L)`. More generally, components for which such lifts are meaningless (e.g. character strings) are copied verbatim.

      ? lift(Mod(5,3))
      %1 = 2
      ? lift(3 + O(3^9))
      %2 = 3
      ? lift(Mod(x,x^2+1))
      %3 = x
      ? lift(Mod(x,x^2+1))
      %4 = x

Lifts are performed recursively on an object components, but only by one level: once a `t_POLMOD` is lifted, the components of the result are not lifted further.

      ? lift(x * Mod(1,3) + Mod(2,3))
      %4 = x + 2
      ? lift(x * Mod(y,y^2+1) + Mod(2,3))
      %5 = y*x + Mod(2, 3)   \\  do you understand this one?
      ? lift(x * Mod(y,y^2+1) + Mod(2,3), 'x)
      %6 = Mod(y, y^2 + 1)*x + Mod(Mod(2, 3), y^2 + 1)
      ? lift(%, y)
      %7 = y*x + Mod(2, 3)

To recursively lift all components not only by one level, but as long as possible, use `liftall`. To lift only `t_INTMOD`s and `t_PADIC`s components, use `liftint`. To lift only `t_POLMOD`s components, use `liftpol`. Finally, `centerlift` allows to lift `t_INTMOD`s and `t_PADIC`s using centered residues (lift of smallest absolute value).

The library syntax is `GEN lift0(GEN x, long v = -1)`, where `v` is a variable number. Also available is `GEN lift(GEN x)` corresponding to `lift0(x,-1)`.

#### liftall(x)

Recursively lift all components of x from Z/nZ to Z, from Q_p to Q (as `truncate`), and polmods to polynomials. `t_FFELT` are not lifted, nor are List elements: you may convert the latter to vectors first, or use `apply(liftall,L)`. More generally, components for which such lifts are meaningless (e.g. character strings) are copied verbatim.

      ? liftall(x * (1 + O(3)) + Mod(2,3))
      %1 = x + 2
      ? liftall(x * Mod(y,y^2+1) + Mod(2,3)*Mod(z,z^2))
      %2 = y*x + 2*z

The library syntax is `GEN liftall(GEN x)`.

#### liftint(x)

Recursively lift all components of x from Z/nZ to Z and from Q_p to Q (as `truncate`). `t_FFELT` are not lifted, nor are List elements: you may convert the latter to vectors first, or use `apply(liftint,L)`. More generally, components for which such lifts are meaningless (e.g. character strings) are copied verbatim.

      ? liftint(x * (1 + O(3)) + Mod(2,3))
      %1 = x + 2
      ? liftint(x * Mod(y,y^2+1) + Mod(2,3)*Mod(z,z^2))
      %2 = Mod(y, y^2 + 1)*x + Mod(Mod(2*z, z^2), y^2 + 1)

The library syntax is `GEN liftint(GEN x)`.

#### liftpol(x)

Recursively lift all components of x which are polmods to polynomials. `t_FFELT` are not lifted, nor are List elements: you may convert the latter to vectors first, or use `apply(liftpol,L)`. More generally, components for which such lifts are meaningless (e.g. character strings) are copied verbatim.

      ? liftpol(x * (1 + O(3)) + Mod(2,3))
      %1 = (1 + O(3))*x + Mod(2, 3)
      ? liftpol(x * Mod(y,y^2+1) + Mod(2,3)*Mod(z,z^2))
      %2 = y*x + Mod(2, 3)*z

The library syntax is `GEN liftpol(GEN x)`.

#### norm(x)

Algebraic norm of x, i.e. the product of x with its conjugate (no square roots are taken), or conjugates for polmods. For vectors and matrices, the norm is taken componentwise and hence is not the L^2-norm (see `norml2`). Note that the norm of an element of R is its square, so as to be compatible with the complex norm.

The library syntax is `GEN gnorm(GEN x)`.

#### numerator(x)

Numerator of x. The meaning of this is clear when x is a rational number or function. If x is an integer or a polynomial, it is treated as a rational number or function, respectively, and the result is x itself. For polynomials, you probably want to use

      numerator( content(x) )

instead.

In other cases, `numerator(x)` is defined to be `denominator(x)*x`. This is the case when x is a vector or a matrix, but also for `t_COMPLEX` or `t_QUAD`. In particular since a `t_PADIC` or `t_INTMOD` has denominator 1, its numerator is itself.

Warning. Multivariate objects are created according to variable priorities, with possibly surprising side effects (x/y is a polynomial, but y/x is a rational function). See Section [Label: se:priority].

The library syntax is `GEN numer(GEN x)`.

#### numtoperm(n,k)

Generates the k-th permutation (as a row vector of length n) of the numbers 1 to n. The number k is taken modulo n!, i.e. inverse function of `permtonum`. The numbering used is the standard lexicographic ordering, starting at 0.

The library syntax is `GEN numtoperm(long n, GEN k)`.

#### padicprec(x,p)

Absolute p-adic precision of the object x. This is the minimum precision of the components of x. The result is `LONG_MAX` (2^{31}-1 for 32-bit machines or 2^{63}-1 for 64-bit machines) if x is an exact object.

The library syntax is `long padicprec(GEN x, GEN p)`.

#### permtonum(x)

Given a permutation x on n elements, gives the number k such that x = `numtoperm(n,k)`, i.e. inverse function of `numtoperm`. The numbering used is the standard lexicographic ordering, starting at 0.

The library syntax is `GEN permtonum(GEN x)`.

#### precision(x,{n})

The function has two different behaviors according to whether n is present or not.

If n is missing, the function returns the precision in decimal digits of the PARI object x. If x is an exact object, the largest single precision integer is returned.

      ? precision(exp(1e-100))
      %1 = 134                \\ 134 significant decimal digits
      ? precision(2 + x)
      %2 = 2147483647         \\ exact object
      ? precision(0.5 + O(x))
      %3 = 28                 \\ floating point accuracy, NOT series precision
      ? precision( [ exp(1e-100), 0.5 ] )
      %4 = 28                 \\ minimal accuracy among components

The return value for exact objects is meaningless since it is not even the same on 32 and 64-bit machines. The proper way to test whether an object is exact is

      ? isexact(x) = precision(x) == precision(0)

If n is present, the function creates a new object equal to x with a new "precision" n. (This never changes the type of the result. In particular it is not possible to use it to obtain a polynomial from a power series; for that, see `truncate`.) Now the meaning of precision is different from the above (floating point accuracy), and depends on the type of x:

For exact types, no change. For x a vector or a matrix, the operation is done componentwise.

For real x, n is the number of desired significant decimal digits. If n is smaller than the precision of x, x is truncated, otherwise x is extended with zeros.

For x a p-adic or a power series, n is the desired number of significant p-adic or X-adic digits, where X is the main variable of x. (Note: yes, this is inconsistent.) Note that the precision is a priori distinct from the exponent k appearing in O(*^k); it is indeed equal to k if and only if x is a p-adic or X-adic unit.

      ? precision(1 + O(x), 10)
      %1 = 1 + O(x^10)
      ? precision(x^2 + O(x^10), 3)
      %2 = x^2 + O(x^5)
      ? precision(7^2 + O(7^10), 3)
      %3 = 7^2 + O(7^5)

For the last two examples, note that x^2 + O(x^5) = x^2(1 + O(x^3)) indeed has 3 significant coefficients

The library syntax is `GEN precision0(GEN x, long n)`. Also available are `GEN gprec(GEN x, long n)` and `long precision(GEN x)`. In both, the accuracy is expressed in words (32-bit or 64-bit depending on the architecture).

#### random({N = 2^{{31}}})

Returns a random element in various natural sets depending on the argument N.

* `t_INT`: returns an integer uniformly distributed between 0 and N-1. Omitting the argument is equivalent to `random(2^31)`.

* `t_REAL`: returns a real number in [0,1[ with the same accuracy as N (whose mantissa has the same number of significant words).

* `t_INTMOD`: returns a random intmod for the same modulus.

* `t_FFELT`: returns a random element in the same finite field.

* `t_VEC` of length 2, N = [a,b]: returns an integer uniformly distributed between a and b.

* `t_VEC` generated by `ellinit` over a finite field k (coefficients are `t_INTMOD`s modulo a prime or `t_FFELT`s): returns a "random" k-rational affine point on the curve. More precisely if the curve has a single point (at infinity!) we return it; otherwise we return an affine point by drawing an abscissa uniformly at random until `ellordinate` succeeds. Note that this is definitely not a uniform distribution over E(k), but it should be good enough for applications.

* `t_POL` return a random polynomial of degree at most the degree of N. The coefficients are drawn by applying `random` to the leading coefficient of N.

      ? random(10)
      %1 = 9
      ? random(Mod(0,7))
      %2 = Mod(1, 7)
      ? a = ffgen(ffinit(3,7), 'a); random(a)
      %3 = a^6 + 2*a^5 + a^4 + a^3 + a^2 + 2*a
      ? E = ellinit([3,7]*Mod(1,109)); random(E)
      %4 = [Mod(103, 109), Mod(10, 109)]
      ? E = ellinit([1,7]*a^0); random(E)
      %5 = [a^6 + a^5 + 2*a^4 + 2*a^2, 2*a^6 + 2*a^4 + 2*a^3 + a^2 + 2*a]
      ? random(Mod(1,7)*x^4)
      %6 = Mod(5, 7)*x^4 + Mod(6, 7)*x^3 + Mod(2, 7)*x^2 + Mod(2, 7)*x + Mod(5, 7)

These variants all depend on a single internal generator, and are independent from your operating system's random number generators. A random seed may be obtained via `getrand`, and reset using `setrand`: from a given seed, and given sequence of `random`s, the exact same values will be generated. The same seed is used at each startup, reseed the generator yourself if this is a problem. Note that internal functions also call the random number generator; adding such a function call in the middle of your code will change the numbers produced.

Technical note. Up to version 2.4 included, the internal generator produced pseudo-random numbers by means of linear congruences, which were not well distributed in arithmetic progressions. We now use Brent's XORGEN algorithm, based on Feedback Shift Registers, see `http://wwwmaths.anu.edu.au/~brent/random.html`. The generator has period 2^{4096}-1, passes the Crush battery of statistical tests of L'Ecuyer and Simard, but is not suitable for cryptographic purposes: one can reconstruct the state vector from a small sample of consecutive values, thus predicting the entire sequence.

The library syntax is `GEN genrand(GEN N = NULL)`.

Also available: `GEN ellrandom(GEN E)` and `GEN ffrandom(GEN a)`.

#### real(x)

Real part of x. In the case where x is a quadratic number, this is the coefficient of 1 in the "canonical" integral basis (1,omega).

The library syntax is `GEN greal(GEN x)`.

#### round(x,{&e})

If x is in R, rounds x to the nearest integer (rounding to + oo in case of ties), then and sets e to the number of error bits, that is the binary exponent of the difference between the original and the rounded value (the "fractional part"). If the exponent of x is too large compared to its precision (i.e. e > 0), the result is undefined and an error occurs if e was not given.

Important remark. Contrary to the other truncation functions, this function operates on every coefficient at every level of a PARI object. For example {truncate}((2.4*X^2-1.7)/(X)) = 2.4*X, whereas {round}((2.4*X^2-1.7)/(X)) = (2*X^2-2)/(X). An important use of `round` is to get exact results after an approximate computation, when theory tells you that the coefficients must be integers.

The library syntax is `GEN round0(GEN x, GEN *e = NULL)`. Also available are `GEN grndtoi(GEN x, long *e)` and `GEN ground(GEN x)`.

#### simplify(x)

This function simplifies x as much as it can. Specifically, a complex or quadratic number whose imaginary part is the integer 0 (i.e. not `Mod(0,2)` or `0.E-28`) is converted to its real part, and a polynomial of degree 0 is converted to its constant term. Simplifications occur recursively.

This function is especially useful before using arithmetic functions, which expect integer arguments:

      ? x = 2 + y - y
      %1 = 2
      ? isprime(x)
        ***   at top-level: isprime(x)
        ***                 ^----------
        *** isprime: not an integer argument in an arithmetic function
      ? type(x)
      %2 = "t_POL"
      ? type(simplify(x))
      %3 = "t_INT"

Note that GP results are simplified as above before they are stored in the history. (Unless you disable automatic simplification with `\y`, that is.) In particular

      ? type(%1)
      %4 = "t_INT"

The library syntax is `GEN simplify(GEN x)`.

#### sizebyte(x)

Outputs the total number of bytes occupied by the tree representing the PARI object x.

The library syntax is `long gsizebyte(GEN x)`. Also available is `long gsizeword(GEN x)` returning a number of words.

#### sizedigit(x)

Outputs a quick bound for the number of decimal digits of (the components of) x, off by at most 1. If you want the exact value, you can use `#Str(x)`, which is slower.

The library syntax is `long sizedigit(GEN x)`.

#### truncate(x,{&e})

Truncates x and sets e to the number of error bits. When x is in R, this means that the part after the decimal point is chopped away, e is the binary exponent of the difference between the original and the truncated value (the "fractional part"). If the exponent of x is too large compared to its precision (i.e. e > 0), the result is undefined and an error occurs if e was not given. The function applies componentwise on vector / matrices; e is then the maximal number of error bits. If x is a rational function, the result is the "integer part" (Euclidean quotient of numerator by denominator) and e is not set.

Note a very special use of `truncate`: when applied to a power series, it transforms it into a polynomial or a rational function with denominator a power of X, by chopping away the O(X^k). Similarly, when applied to a p-adic number, it transforms it into an integer or a rational number by chopping away the O(p^k).

The library syntax is `GEN trunc0(GEN x, GEN *e = NULL)`. The following functions are also available: `GEN gtrunc(GEN x)` and `GEN gcvtoi(GEN x, long *e)`.

#### valuation(x,p)

Computes the highest exponent of p dividing x. If p is of type integer, x must be an integer, an intmod whose modulus is divisible by p, a fraction, a q-adic number with q = p, or a polynomial or power series in which case the valuation is the minimum of the valuation of the coefficients.

If p is of type polynomial, x must be of type polynomial or rational function, and also a power series if x is a monomial. Finally, the valuation of a vector, complex or quadratic number is the minimum of the component valuations.

If x = 0, the result is `LONG_MAX` (2^{31}-1 for 32-bit machines or 2^{63}-1 for 64-bit machines) if x is an exact object. If x is a p-adic numbers or power series, the result is the exponent of the zero. Any other type combinations gives an error.

The library syntax is `long gvaluation(GEN x, GEN p)`.

#### variable({x})

Gives the main variable of the object x (the variable with the highest priority used in x), and p if x is a p-adic number. Return 0 if x has no variable associated to it.

      ? variable(x^2 + y)
      %1 = x
      ? variable(1 + O(5^2))
      %2 = 5
      ? variable([x,y,z,t])
      %3 = x
      ? variable(1)
      %4 = 0

The construction

         if (!variable(x),...)

can be used to test whether a variable is attached to x.

If x is omitted, returns the list of user variables known to the interpreter, by order of decreasing priority. (Highest priority is x, which always come first.)

The library syntax is `GEN gpolvar(GEN x = NULL)`. However, in library mode, this function should not be used for x non-`NULL`, since `gvar` is more appropriate. Instead, for x a p-adic (type `t_PADIC`), p is gel(x,2); otherwise, use `long gvar(GEN x)` which returns the variable number of x if it exists, `NO_VARIABLE` otherwise, which satisfies the property `varncmp`(`NO_VARIABLE`, v) > 0 for all valid variable number v, i.e. it has lower priority than any variable.